- Qt 5.3
- Qt Multimedia
- QML Video Example
- SeekControl.qml Example File
- Qt 5.3.2 Reference Documentation

# SeekControl.qml Example File

video/qmlvideo/qml/qmlvideo/SeekControl.qml

    /****************************************************************************
    **
    ** Copyright (C) 2013 Digia Plc and/or its subsidiary(-ies).
    ** Contact: http://www.qt-project.org/legal
    **
    ** This file is part of the Qt Mobility Components.
    **
    ** $QT_BEGIN_LICENSE:LGPL$
    ** Commercial License Usage
    ** Licensees holding valid commercial Qt licenses may use this file in
    ** accordance with the commercial license agreement provided with the
    ** Software or, alternatively, in accordance with the terms contained in
    ** a written agreement between you and Digia.  For licensing terms and
    ** conditions see http://qt.digia.com/licensing.  For further information
    ** use the contact form at http://qt.digia.com/contact-us.
    **
    ** GNU Lesser General Public License Usage
    ** Alternatively, this file may be used under the terms of the GNU Lesser
    ** General Public License version 2.1 as published by the Free Software
    ** Foundation and appearing in the file LICENSE.LGPL included in the
    ** packaging of this file.  Please review the following information to
    ** ensure the GNU Lesser General Public License version 2.1 requirements
    ** will be met: http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
    **
    ** In addition, as a special exception, Digia gives you certain additional
    ** rights.  These rights are described in the Digia Qt LGPL Exception
    ** version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
    **
    ** GNU General Public License Usage
    ** Alternatively, this file may be used under the terms of the GNU
    ** General Public License version 3.0 as published by the Free Software
    ** Foundation and appearing in the file LICENSE.GPL included in the
    ** packaging of this file.  Please review the following information to
    ** ensure the GNU General Public License version 3.0 requirements will be
    ** met: http://www.gnu.org/copyleft/gpl.html.
    **
    **
    ** $QT_END_LICENSE$
    **
    ****************************************************************************/

    import QtQuick 2.0

    Item {
        id: seekControl
        height: 46
        property int duration: 0
        property int playPosition: 0
        property int seekPosition: 0
        property bool enabled: true
        property bool seeking: false

        Rectangle {
            id: background
            anchors.fill: parent
            color: "black"
            opacity: 0.3
        }

        Rectangle {
            id: progressBar
            anchors { left: parent.left; top: parent.top; bottom: parent.bottom }
            width: seekControl.duration == 0 ? 0 : background.width * seekControl.playPosition / seekControl.duration
            color: "black"
            opacity: 0.7
        }

        Text {
            width: 90
            anchors { left: parent.left; top: parent.top; bottom: parent.bottom; leftMargin: 10 }
            font { family: "Nokia Sans S60"; pixelSize: 24 }
            horizontalAlignment: Text.AlignLeft
            verticalAlignment: Text.AlignVCenter
            color: "white"
            smooth: true
            text: formatTime(playPosition)
        }

        Text {
            width: 90
            anchors { right: parent.right; top: parent.top; bottom: parent.bottom; rightMargin: 10 }
            font { family: "Nokia Sans S60"; pixelSize: 24 }
            horizontalAlignment: Text.AlignRight
            verticalAlignment: Text.AlignVCenter
            color: "white"
            smooth: true
            text: formatTime(duration)
        }

        Image {
            id: progressHandle
            height: 46
            width: 10
            source: mouseArea.pressed ? "qrc:/images/progress_handle_pressed.svg" : "qrc:/images/progress_handle.svg"
            anchors.verticalCenter: progressBar.verticalCenter
            x: seekControl.duration == 0 ? 0 : seekControl.playPosition / seekControl.duration * 630

            MouseArea {
                id: mouseArea
                anchors { horizontalCenter: parent.horizontalCenter; bottom: parent.bottom }
                height: 46+16
                width: height
                enabled: seekControl.enabled
                drag {
                    target: progressHandle
                    axis: Drag.XAxis
                    minimumX: 0
                    maximumX: 631
                }
                onPressed: {
                    seekControl.seeking = true;
                }
                onCanceled: {
                    seekControl.seekPosition = progressHandle.x * seekControl.duration / 630
                    seekControl.seeking = false
                }
                onReleased: {
                    seekControl.seekPosition = progressHandle.x * seekControl.duration / 630
                    seekControl.seeking = false
                    mouse.accepted = true
                }
            }
        }

        Timer { // Update position also while user is dragging the progress handle
            id: seekTimer
            repeat: true
            interval: 300
            running: seekControl.seeking
            onTriggered: {
                seekControl.seekPosition = progressHandle.x*seekControl.duration/630
            }
        }

        function formatTime(timeInMs) {
            if (!timeInMs || timeInMs <= 0) return "0:00"
            var seconds = timeInMs / 1000;
            var minutes = Math.floor(seconds / 60)
            seconds = Math.floor(seconds % 60)
            if (seconds < 10) seconds = "0" + seconds;
            return minutes + ":" + seconds
        }
    }